
Suppose that we have many files to read in.  They could be several EXCEL spreadsheets or many small text files.  Typing in all of their names as in Example 5 of APMisc1
 can be quite tedious.  Instead we can use a small text file with a list of their names to automatically read them in and concatenate them into one large SAS data set.  The discussion below will assume that all work occurs in one directory which, for example, I will call H:\working\project1.  Further, I will assume that you have set the working directory for your SAS session to this directory
.
Step 1: Getting the list of files
If all of the files are present in one directory then we can use an old-fashioned DOS command to obtain the list of files.  If you have access to the SAS X command then this is very easy.  Suppose that we are going to import all those files with an extension of XLS.  Then, in SAS run:  


X 'dir *.xls > filelist.txt';

This is the DOS directory command (dir) requesting that all files with the xls extension be listed.  The output is “piped” (via the > sign) to the file filelist.txt which is either created or replaced in your current directory.  Recall that file names in DOS can be no more than 8 characters long nor are spaces allowed.
The long method:  For those of us with the X command disabled
, some other trickery is required.  First, you must be able to access the MSDOS command window.  This is most easily accomplished by setting up a desktop icon.  Right click on the desktop, choose new shortcut and type in C:\WINDOWS\system32\command.com as the location of the item.  Click on next and accept the default name, MSDOS.

Now, click on this new icon and navigate to the directory containing your files
.  You may first have to change from the C: hard drive to for instance, the H: drive.  Then use the change directory DOS command to change to the directory where your files are stored.  For my example directory we would put in the following commands:


Change hard drive by:
h: <enter>  


Change directory by:
cd working\project1 <enter>.  
You may run into problems if any name is longer than 8 characters or contains spaces.
Another approach is to map a network drive to the directory containing your data files.  This avoids any problems with directory names.  You have to include the server name when you do this.  You can find what this is by looking at the windows explorer.  For instance, my H: drive is denoted as Wbergeru$ on gimlet.
To map the network drive, choose the tools drop-down menu in Windows Explorer and choose map network drive.   Fill in the dialog box by choosing a drive letter and filling in the folder name.  For the current example, my folder name is \\gimlet\Wbergeru$\working\project1.
Finally:  Once this is set up, then in the MSDOS command window, enter the drive letter that you chose (e.g., Z:), and then type   dir *.xls > filelist.txt <enter>.  
Close the MSDOS window by entering exit <enter>.  Now, we are ready for the next step
.
Step 2: Reading in the list of names

Now that we have a text file with the list of file names we can read it into SAS.  The directory listing in this file has a number of lines that aren’t relevant as well as extra columns of information that we aren’t interested in using: we just want the file names.
Since we will be using a macro to read in the files, let’s define where the data is using a macro variable, which I’ll call datadir.  We can use either of the following statements to assign the directory name to this macro variable.  The first assignment is explicit while the second will only work IF the working directory within SAS is the directory where the data files are located.
  %let datadir = h:\working\project1;  

  %let datadir = .; * Works for the current working directory;

The following code reads in five columns of data from filelist.txt (t1, t2, t3, t4, filename) but keeps only the last column (filename):

data list; 

  infile "&datadir\filelist.txt" pad missover;  keep filename;

  input (t1 t2 t3 t4) ($) filename $20.0;

  if index(filename,'.') gt 0 then output;  

run;
The infile statement needs the pad option to replace any tabs with spaces, and the missover option stops SAS from reading more data from the next line when the current line is too short.  The input statement simply uses the t1 to t4 variables as place holders to read the fifth column of text.  

Not all lines in the filelist.txt contains filenames and so the if statement checks that the values in the filename variable contains a dot, in which case, it is a file name with an extension.  If we also want to check that we only have EXCEL spreadsheet file names in our data set we can change this line to:
  if substr(filename,(index(filename,'.'))+1,3) in('XLS', 'xls') then output;      

This complicated code checks that the three characters after the first ‘dot’ in the filename match the extension for EXCEL spreadsheet files.  The index function identifies where the dot is in the filename, for example, it might be the tenth character in the name.  The substr function then extracts the three characters appearing after the dot.  If the dot is in the tenth position, then the characters in the 11th, 12th and 13th positions would be extracted.
Step 3: Building the Readin Macro

Now that we have a SAS data set with the list of files that we want to read into SAS, we can build the macro that will do that work for us.  
3.1  First, we define the macro including the name of the final dataset to contain all of the data:

%macro readin (finalfile);
If this is to be a permanent SAS data set, don’t forget to run a libname statement defining the library and include it with the finalfile name. 

3.2  The next step is to create a macro variable that contains the number of files that we want to read in.  We use the call symput function within a null datastep to assign this value to the macro variable list_length (the _null_ data step name means that a new data set is not created).   We then put that value out in the log so that we can see what it is.
** Getting the number of filenames into a macro variable called list_length;

data _null_; 
  set list end = eof; if eof then call symput('list_length',_n_); run; 

%put Number of files is &list_length ; * Writes number to log;

3.3  Now we must start a macro do loop to choose a file name from the list and read the data in from that file.  The loop will go through the whole list of file names.  We need to use another null data step to assign the current file name to the macro variable filename.  It is useful to put the file name into the log so that we can check our program’s process, especially if the program takes a while to run.
** Cycling through all the files and reading the data in;
  %do filen = 1 %to &list_length;  

  ** Get the current filename;
     data _null_; set list; 

       if _n_ = &filen then call symput('filename', filename); run;

     %put File Number &filen. is &filename.; ** Writes name to log; 

3.4  Now we read in the data from each file  Clearly, this next part of the macro can vary quite a bit depending upon the files you are reading in.  I give an example of importing just one worksheet (called data) from each of several EXCEL spreadsheets.  Each worksheet is imported into temporary SAS data sets called Tmp1, Tmp2, Tmp3, etc.  In this example a specific range of the sheet, A6:C17, is specified for importing.  This can be left out if reading in the whole sheet.
PROC IMPORT OUT= WORK.tmp&filen.
  DATAFILE= "&datadir\&filename." 

  DBMS=EXCEL REPLACE; SHEET="Data$a6:c17"; 
  GETNAMES=YES; MIXED=NO; SCANTEXT=YES; USEDATE=YES; SCANTIME=YES;

  RUN;

We could also add a step to modify the temporary data sets in some way.  The code below adds a variable called siteno that includes the place of the spreadsheet in the list of filenames, and could be used to identify which worksheet the data is from.

** Adding a variable to dataset identifying that dataset;
data tmp&filen.; set tmp&filen.;  siteno = &filen.;  run;

3.5  Now that the data has been read in, we must add it to the data already saved and close both the do loop and the macro.  For the first file we’ve read in, we create the SAS data set specified by the macro variable finalfile.  For later files, we append the data.
  %if &filen. = 1 %then %do; 

              data &finalfile; set tmp&filen.;            run; %end;

  %else %do;  data &finalfile; set &finalfile tmp&filen.; run; %end;

  %end; 

%mend;

Now we can invoke the macro by, for instance: 

%readin(here.testxls);

The file containing all of the data will be in a permanent SAS data set called here.testxls.
3.6  If we need to test the code in step 3.4 that reads in the data we can use the following:
  %let datadir = .; * Works for the current working directory;

  %let filen = 1;  %let filename = site1.xls; * Name of a file;
  PROC IMPORT OUT= WORK.tmp&filen.
    DATAFILE= "&datadir\&filename." 

    DBMS=EXCEL REPLACE; SHEET="Data$a6:c17"; 
    GETNAMES=YES;  MIXED=NO; SCANTEXT=YES;  USEDATE=YES; SCANTIME=YES;

  RUN;

  data tmp&filen.; set tmp&filen.;  site = &filen.;  run;
Appendix:  Final Program

/** Readin Macro - program to read in many similar files and 

                   concatenate them into one large sas data set      **/

/** The file filelist.txt is created using DOS or the MSDOS prompt  
    unless you can use the SAS x command:                            **/

    x 'dir *.xls > filelist.txt';

* Directory for the permanent final dataset;
  libname here '.';  * This refers to the current working directory
* Directory where the many small files are located;
  %let datadir = h:\working\project1;  

  %let datadir = .; * Also works if data in the current working directory;
** Now we read in the list of filenames in the datadir directory;

data list; 

  infile "&datadir\filelist.txt" pad missover;  keep filename;

  input (t1 t2 t3 t4) ($) filename $20.0;

  if substr(filename, (index(filename,'.'))+1,3) in ('XLS', 'xls') then output; 

run;

/** Macro to read in and concatenate the data files  **/
%macro readin (finalfile);

** Getting the number of filenames into a macro variable called list_length;
   data _null_; set list end = eof; if eof then call symput('list_length',_n_); run;

   %put Number of files is &list_length ; * Writes to log so we can check progress;
** Cycling through all the files and reading the data in;
  %do filen = 1 %to &list_length;  

  ** Get the current filename;
  data _null_; set list; if _n_ = &filen then call symput('filename', filename); run;

  %put File Number &filen. is &filename.; ** Goes to log so we can check progress; 

***  Here is where you put in the proc import procedure for instance - the "meat";
  PROC IMPORT OUT= WORK.tmp&filen.
    DATAFILE= "&datadir\&filename." 

    DBMS=EXCEL REPLACE; SHEET="Data$a6:c17"; ** A specific range has been used here;
    GETNAMES=YES;  MIXED=NO; SCANTEXT=YES;  USEDATE=YES; SCANTIME=YES;

  RUN;

  data tmp&filen.; set tmp&filen.; site = &filen.;  ** Adding an identifier variable;
  run;

****  End of programming with the individual files – the "meat";
** Concatenating the tmp datasets into the final SAS data file;
  %if &filen. = 1 %then %do; 

              data &finalfile; set tmp&filen.;            run; %end;

  %else %do;  data &finalfile; set &finalfile tmp&filen.; run; %end;

  %end; 

%mend;

****  Running the macro and defining the final data set name as here.testxls;
%readin(here.testxls);















� This material is provided for informational purposes only; no guarantees are implied.


� This can be found at our ftp site: //ftp.for.gov.bc.ca/hre/external/!publish/sas/


� This is the directory shown at the extreme bottom right of your SAS windows – it can be easily changed by double-clicking on it.


� That is, for those of us in the Ministry of Forests and Range with “managed” machines!


� You have to use the keyboard here – this is ancient stuff!  No point and clicking!


� You might consider disconnecting this network drive if you won’t be using it this way again.

